package scriptConsole

import com.atlassian.jira.bc.issue.link.IssueLinkService
import com.atlassian.jira.bc.issue.search.SearchService
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.event.type.EventDispatchOption
import com.atlassian.jira.issue.Issue
import com.atlassian.jira.issue.IssueManager
import com.atlassian.jira.issue.MutableIssue
import com.atlassian.jira.issue.link.IssueLink
import com.atlassian.jira.issue.link.IssueLinkManager
import com.atlassian.jira.issue.link.IssueLinkType
import com.atlassian.jira.issue.search.SearchResults
import com.atlassian.jira.security.JiraAuthenticationContext
import com.atlassian.jira.user.ApplicationUser
import com.atlassian.jira.web.bean.PagerFilter
import groovy.transform.Field
import org.apache.log4j.Level
import org.apache.log4j.Logger

/**
 * Changes the Epic Links of Jira Epics into the Agile Hive Link.
 */

@Field Logger logger = (Logger) log;
logger.setLevel(Level.WARN);

@Field String LINK_DIRECTION_OUTWARD = "OUTWARD";
@Field String LINK_DIRECTION_INWARD = "INWARD";
@Field String LINK_NAME = "Agile Hive Link";
@Field String LINK_DIRECTION = LINK_DIRECTION_OUTWARD;

//JQL for the EPICs to be changed (Important! There may only be epics in the JQL)
@Field String EPIC_JQL = "project = XYZ AND issuetype = epic"

@Field List<Issue> epics = getAllEpics();
@Field IssueLinkType issueLinkType = getIssueLinkType(LINK_NAME);

IssueManager issueManager = (IssueManager) ComponentAccessor.getComponent(IssueManager.class);
for (Issue docIssue : epics) {
    MutableIssue epic = issueManager.getIssueObject(docIssue.getKey());
    handleIssue(epic);
    updateIssue(epic);
}
logger.debug("Done");

void handleIssue(Issue epic) {
    logger.debug("epic ${epic.key}");
    List<IssueLink> issuesInEpicLinks = getIssueLinks(epic, "Epic-Story Link", LINK_DIRECTION_OUTWARD);
    Set<Issue> issuesInEpic = getIssuesFromLinks(issuesInEpicLinks, LINK_DIRECTION_OUTWARD);
    for (Issue issue : issuesInEpic) {
        logger.warn("epic ${epic} issue ${issue} issuetype ${issue.getIssueType().getName()}")
            addIssueLink(issue, epic, getIssueLinkType(LINK_NAME));
    }
}

List<Issue> getAllEpics() {
    return getIssuesByJQL(EPIC_JQL)
}

List<Issue> getIssuesByJQL(String jqlSearch) {
    SearchService searchService = ComponentAccessor.getComponent(SearchService.class);
    ApplicationUser user = ComponentAccessor.getJiraAuthenticationContext().getLoggedInUser();
    logger.info("Searching JQL: ${jqlSearch}");
    SearchService.ParseResult parseResult = searchService.parseQuery(user, jqlSearch);
    if (parseResult.isValid()) {
        SearchResults searchResult = searchService.search(user, parseResult.getQuery(), PagerFilter.getUnlimitedFilter());
        return searchResult.getResults();
    }
    logger.error("JQL '${jqlSearch}' is invalid. ${parseResult.getErrors()}");
    return Collections.emptyList();
}

private void addIssueLink(Issue issue, Issue parent, IssueLinkType issueLinkType) {
    IssueLinkManager issueLinkManager = ComponentAccessor.getIssueLinkManager();
    issueLinkManager.createIssueLink(issue.getId(), parent.getId(), issueLinkType.getId(), 0L, getCurrentUser());
    updateIssue(issue);
}

private ApplicationUser getCurrentUser() {
    JiraAuthenticationContext authenticationContext = ComponentAccessor.getJiraAuthenticationContext();
    return authenticationContext.getLoggedInUser();
}

private IssueLinkType getIssueLinkType(String issueLinkTypeName) {
    IssueLinkService issueLinkService = ComponentAccessor.getComponent(IssueLinkService.class);
    def issueLinkTypes = issueLinkService.getIssueLinkTypes()
    logger.debug("issueLinkTypes ${issueLinkTypes}");
    IssueLinkType issueLinkTypeRealizes = issueLinkTypes.find { it.name == issueLinkTypeName };
    return issueLinkTypeRealizes;
}

List<IssueLink> getIssueLinks(Issue issue, String linkName, String linkDirection) {
    IssueLinkManager issueLinkManager = ComponentAccessor.getIssueLinkManager();
    List<IssueLink> links = new ArrayList<>();
    if (linkDirection == LINK_DIRECTION_INWARD) {
        links.addAll(issueLinkManager.getInwardLinks(issue.getId()));
    } else if (linkDirection == LINK_DIRECTION_OUTWARD) {
        links.addAll(issueLinkManager.getOutwardLinks(issue.getId()));
    }

    List<IssueLink> filteredLinks = links.findAll { it.getIssueLinkType().getName() == linkName }
    logger.debug("found ${filteredLinks.size()} issueLinks");
    return filteredLinks;
}

Set<Issue> getIssuesFromLinks(List<IssueLink> issueLinks, String linkDirection) {
    Set<Issue> issues = new HashSet<>();
    for (IssueLink link : issueLinks) {
        logger.debug(" dest ${link.getDestinationObject().getKey()} source ${link.getSourceObject().getKey()}")
        if (linkDirection == LINK_DIRECTION_INWARD) {
            issues.add(link.getSourceObject());
        } else if (linkDirection == LINK_DIRECTION_OUTWARD) {
            issues.add(link.getDestinationObject());
        }
    }
    return issues;
}

void updateIssue(Issue issue) {
    JiraAuthenticationContext authenticationContext = ComponentAccessor.getJiraAuthenticationContext();
    ApplicationUser user = authenticationContext.getLoggedInUser();
    IssueManager issueManager = (IssueManager) ComponentAccessor.getComponent(IssueManager.class);
    logger.debug("throw Issue Updated Event for issue ${issue.key}")
    issueManager.updateIssue(user, (MutableIssue) issue, EventDispatchOption.ISSUE_UPDATED, false);
}